/*********************************************************************NVMH3****
File:  $Id: //sw/devtools/SDK/9.5/SDK/MEDIA/HLSL/post_bleach_bypass.fx#3 $

Copyright NVIDIA Corporation 2004
TO THE MAXIMUM EXTENT PERMITTED BY APPLICABLE LAW, THIS SOFTWARE IS PROVIDED
*AS IS* AND NVIDIA AND ITS SUPPLIERS DISCLAIM ALL WARRANTIES, EITHER EXPRESS
OR IMPLIED, INCLUDING, BUT NOT LIMITED TO, IMPLIED WARRANTIES OF MERCHANTABILITY
AND FITNESS FOR A PARTICULAR PURPOSE.  IN NO EVENT SHALL NVIDIA OR ITS SUPPLIERS
BE LIABLE FOR ANY SPECIAL, INCIDENTAL, INDIRECT, OR CONSEQUENTIAL DAMAGES
WHATSOEVER (INCLUDING, WITHOUT LIMITATION, DAMAGES FOR LOSS OF BUSINESS PROFITS,
BUSINESS INTERRUPTION, LOSS OF BUSINESS INFORMATION, OR ANY OTHER PECUNIARY LOSS)
ARISING OUT OF THE USE OF OR INABILITY TO USE THIS SOFTWARE, EVEN IF NVIDIA HAS
BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGES.

******************************************************************************/

#include <include\\Quad.fxh>

float Script : STANDARDSGLOBAL <
    string UIWidget = "none";
    string ScriptClass = "scene";
    string ScriptOrder = "postprocess";
    string ScriptOutput = "color";
	string Script = "Technique=Main";
> = 0.8;

float4 ClearColor <
	string UIName = "Background";
	string UIWidget = "color";
> = {0.3,0.3,0.3,1.0};

float ClearDepth < string UIWidget = "none"; > = 1.0;

///////////////////////////////////////////////////////////
///////////////////////////// Render-to-Texture Data //////
///////////////////////////////////////////////////////////

DECLARE_QUAD_TEX(SceneTexture,SceneSampler,"A8R8G8B8")
DECLARE_QUAD_DEPTH_BUFFER(DepthBuffer, "D24S8")

/////////////////////////////////////////////////////
//// Tweakables /////////////////////////////////////
/////////////////////////////////////////////////////

float Opacity <
    string UIWidget = "slider";
    float uimin = 0.0;
    float uimax = 1.0;
    float uistep = 0.01;
    string UIName = "Blend Opacity";
> = 1.0;

/**************************************/
/********* blend pixel shaders ********/
/**************************************/

QUAD_REAL4 bypassPS(QuadVertexOutput IN) : COLOR {
	QUAD_REAL4 base = tex2D(SceneSampler, IN.UV);
    QUAD_REAL3 lumCoeff = QUAD_REAL4(0.25,0.65,0.1,0);
	QUAD_REAL lum = dot(lumCoeff,base.rgb);
	QUAD_REAL3 blend = lum.rrr;
    QUAD_REAL L = min(1,max(0,10*(lum- 0.45)));
    QUAD_REAL3 result1 = 2.0f * base.rgb * blend;
    QUAD_REAL3 result2 = 1.0f - 2.0f*(1.0f-blend)*(1.0f-base.rgb);
	QUAD_REAL3 newColor = lerp(result1,result2,L);
    QUAD_REAL A2 = Opacity * base.a;
    QUAD_REAL3 mixRGB = A2 * newColor.rgb;
    mixRGB += ((1.0f-A2) * base.rgb);
	return QUAD_REAL4(mixRGB,base.a);
}

/*******************************************************************/
/************* TECHNIQUES ******************************************/
/*******************************************************************/

technique Main <
	string Script =
			"RenderColorTarget0=SceneTexture;"
	        "RenderDepthStencilTarget=DepthBuffer;"
	        	"ClearSetColor=ClearColor;"
	        	"ClearSetDepth=ClearDepth;"
   				"Clear=Color;"
				"Clear=Depth;"
			"ScriptExternal=color;"
        	"Pass=p0;";
> {
    pass p0 <
    	string Script = "RenderColorTarget0=;"
    					"RenderDepthStencilTarget=;"
    					"Draw=Buffer;";
    > {
		cullmode = none;
		ZEnable = false;
		ZWriteEnable = false;
		VertexShader = compile vs_2_0 ScreenQuadVS();
		PixelShader = compile ps_2_a bypassPS();
    }
}

/***************************** eof ***/